***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 17, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5526-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.448
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=211.3  VTO=2.32  LEVEL=3  VMAX=5e4  ETA=0.01 GAMMA=0.78 NFS=4.859e11)
Rd     d1    d2    3.85m    TC=3.9m,5u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=33  TBV1=4.105e-4 TBV2=5.05e-9  CJO=1.200e-9  M=8.712e-1  VJ=8.538)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=8.353e-20  N=5.564e-1  RS=4e-8  EG=1.10  TT=20n IKF=5.325e-3 TIKF=7.5e-4)
Rdiode  d1  21    3.285e-3 TC=2.6m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.845e-10
.MODEL     DGD    D(CJO=1.845e-10   M=1.314   VJ=6.160)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    7.504e-10
.ENDS PJQ5526-AU
*$
